;___________________________________________________________________________________________

FUNCTION int Ecat_Change_Config(int nEth, int addr, bool sts, bool restartEcat, int@ phase)

; it performs the following operations :

; 1 set the ethercat in INIT state

; 2 change the device status

; 3 wait for the restart Ecat flag

; 4 set the ethercat in OPERATIONAL state

; 5 wait for OPERATIONAL state is reached, if not an error is set

; 6 when OPERATIONAL state is reached, the alarm due to this operation are reset

;

; parameters

; nEth  number of ethernet (1 -:-...)

; addr  device config_addr

; sts   1 --> device present  0 --> device absent

; restartEcat  flag to command the restart of the ethercat line (to be set after that the

;               device has been physically removed or restored to ethercat line)

; phase  working fase to be set to 0 to restart the opreation

; return

;   0   operation in execution

;   1   operation to change the status done, waiting to 'restartEcat'

;   2   operation to restart ethercat line  is done

;  -1   no such device

;  -2   illegal phase

;  -3   unable to  restart ecat , check device

    select(phase)

        default

            phase = -2

        case -2

            return -2       ; illegal phase

        case -3

            return -3       ; unable to restart ecat , check device

        case -1

            return -1       ; error .. no such device

        case 0

            ; set ethercat line in init mode

            _if(nEth = 0)       ; 0 means alla ethercat lines   

                nEth = -1       ; not acceptable here

            esitoECC = ecat_set_state(nEth, 1)

            if (esitoECC = 0)

                phase = 1

            endif

            return 0

        case 1  ; wait the init state

            if(ecat_get_state(nEth) <> 1)

                return 0

            endif

            ; now the modification are allowed

            esitoECC = ecat_dev_on_off(nEth, addr, sts)

; $lin_step esitoecc = ECATSlaveOnOff(neth, addr, sts);

            if(esitoECC < 0)

                phase = -1

                return -1

            endif

            phase = 2

        case 2

            if(not restartEcat)

                return 1

            endif

            ; set ethercat line in operational mode

            esitoECC = ecat_set_state(nEth, 8)

            if(esitoECC = 0)

                phase = 3

                ecatTimeOut = tfb + 10

            endif

            return 0

        case 3

            ecatState = ecat_get_state(nEth)

            if(ecatState = 1)

                if(tfb < ecatTimeOut)

                    return 0

                endif

                ; too much time to change from init state to preopreational....

                ; something wrong

                phase = -3

                return -3

            endif

            ; wait the operational state

            if(ecatState <> 8)

                return 0

            endif

            ; ok the ethercat line is in operational....

            ; clean some alarms due to the operation

            alarm_reset(18, 0)

            alarm_reset(82)

            alarm_reset(83)

            phase = 4

        case 4

            return 2

    end_select

    return -2

END_FUN