Funzione co

Sintassi	i32 co_robj (stru_co_obj stru)
stru	Nome della struttura di tipo stru_co_obj.
Risultato	Variabile di tipo i32 contenente il risultato. Vedi gestione passante e/o gestione bloccante.
Validità	Task, Rule (solo passante).
Note

•Imporre stru.phase = 1 per inizializzare la lettura.

•Il comando di lettura viene inviato al dispositivo remoto e si attende risposta. La variabile stru.phase viene cambiata.
La funzione rende 0.

•Attesa della risposta.
La funzione continua a rendere 0.

•Ricezione risposta con esito positivo. Il valore letto viene scritto in stru.data. RTE cambia stru.phase = 4.
La funzione rende 1.

•Ricezione risposta con esito negativo. RTE cambia stru.phase = 0.
La funzione rende codice di errore:

o-1, parametri illegali (allarme 9900)

o-2, gestore comunicazione occupato

o-3, crash gestore comunicazione (riavvio)

o-4, gestione bloccante non permessa nel task corrente (stru.phase = 1) (rule, ladder). Comando non accettato

o-5, comando a un dispositivo non presente (stru.rid)

o-6, nessuna operazione in esecuzione. stru.phase non inizializzata

o2, comando di cui si è già ricevuto risposta positiva, valore disponibile in data

o>2, codice di errore SDO, vedi tabella sotto

•Imporre stru.phase = -1 per inizializzare la lettura.

•Il comando di lettura viene inviato al dispositivo remoto e si attende risposta. La variabile stru.phase viene cambiata.

•Attesa della risposta. Se la risposta non arriva entro un massimo di 3 secondi la funzione esce con un errore (timeout).

•Ricezione risposta con esito positivo. Il valore letto viene scritto in stru.data. RTE cambia stru.phase = 4.
La funzione rende 1.

•Ricezione risposta con esito negativo. RTE cambia stru.phase = 0.
La funzione rende codice di errore:

o-1, parametri illegali (allarme 9900)

o-2, gestore comunicazione occupato

o-3, crash gestore comunicazione (riavvio)

o-4, gestione bloccante non permessa nel task corrente (stru.phase = 1) (rule, ladder). Comando non accettato

o-5, comando a un dispositivo non presente (stru.rid)

o-6, nessuna operazione in esecuzione. stru.phase non inizializzata

o2, comando di cui si è già ricevuto risposta positiva, valore disponibile in stru.data

o>2, codice di errore SDO, vedi tabella sotto

SDO error code	Descrizione
0x0503 0000	Toggle bit non alternato.
0x0504 0000	Timeout del protocollo SDO.
0x0504 0001	Identificatore del comando client/server non valido o sconosciuto.
0x0504 0002	Dimensione del blocco non valida (solo gestione bloccante).
0x0504 0003	Numero di sequenza non valido (solo gestione bloccante).
0x0504 0004	Errore CRC (solo gestione bloccante).
0x0504 0005	Eccesso di memoria.
0x0601 0000	Accesso non supportato a un oggetto.
0x0601 0001	Tentativo di leggere un oggetto a sola scrittura.
0x0601 0002	Tentativo di scrivere un oggetto a sola lettura.
0x0602 0000	L'oggetto non esiste nel dizionario oggetti.
0x0604 0041	Impossibile mappare l'oggetto sul PDO.
0x0604 0042	Il numero e la lunghezza degli oggetti da mappare supererebbero la lunghezza del PDO.
0x0604 0043	Incompatibilità dei parametri.
0x0604 0047	Incompatibilità interna al dispositivo.
0x0606 0000	Accesso non riuscito a causa di un errore hardware.
0x0607 0010	Il tipo di dati non corrisponde, la lunghezza del parametro di servizio non corrisponde.
0x0607 0012	Il tipo di dati non corrisponde, il parametro della durata del servizio è troppo alto.
0x0607 0013	Il tipo di dati non corrisponde, il parametro della durata del servizio è troppo basso.
0x0609 0011	Il sottoindice non esiste.
0x0609 0030	Superamento del campo di valori del parametro (solo per accesso in scrittura).
0x0609 0031	Valore del parametro scritto troppo alto.
0x0609 0032	Valore del parametro scritto troppo basso.
0x0609 0036	Il valore massimo è inferiore al valore minimo.
0x0800 0000	Errore generale.
0x0800 0020	I dati non possono essere trasferiti o archiviati nell'applicazione.
0x0800 0021	I dati non possono essere trasferiti o archiviati nell'applicazione a causa del controllo locale.
0x0800 0022	I dati non possono essere trasferiti o archiviati nell'applicazione a causa dello stato attuale del dispositivo.
0x0800 0023	La generazione dinamica del dizionario oggetti non riesce o non è presente alcun dizionario oggetti (ad esempio, il dizionario oggetti viene generato da un file e la generazione non riesce a causa di un errore di file).

Esempio di utilizzo:

; SAMPLE CODE

; Global Storage definition

;--------------------------

real CpuDrive_temp[32+1]

real Heater_temp[32+1]

real ControlBoard_temp[32+1]

real updateTime[32+1]

; storage used only by ReadImdTempPT

int whatTemp[32+1]

stru_co_obj sobj[32+1]

lit PER_UPD_TEMP 1.0

..

; Before the main loop

call InitReadImdTemp()

...

; inside the main loop

if(IWantPassThroughReadTempRoutine) ; test a flag to check if i have to use pass-through

; or blocking routines

result = ReadImdTempPT(k) ; k is the RID of the IMD that I want to question

else

result = ReadImdTempBL(k) ; k is the RID of the IMD that I want to question

endif

...

;<0><0><0><0><0><0><0><0><0><0><0><0><0><0><0><0><0><0><0><0><0>

;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

FUNCTION InitReadImdTemp()

real tAct

int k

tAct = tfb

; initialize the tome to start reading after 5 seconds

; in sequence way

for(k=1, k <=32 , INC(k))

updateTime[k] = tAct + PER_UPD_TEMP + ((k-1)*PER_UPD_TEMP/32.0)

whatTemp[k] = 0

end_for

ENDFUN

;<0><0><0><0><0><0><0><0><0><0><0><0><0><0><0><0><0><0><0><0><0>

;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

FUNCTION int ReadImdTempPT(int rid)

; routine 'PASS_THROUGH' version

; function to update the IMD temperature value each PER_UPD_TEMP seconds.

; the information will be set in global storage.

; the function want the RID of the IMD

; give back:

; <0 error

; >2 error (SDO diagnostic)

; 0 no operation

; 1 operation in progress

; 2 all temperature updated

int ero

; check RID value

if(not range(rid, 1, 32))

return -1 ; return error if illegal value

endif

; check if time to update

if(updateTime[rid] <= tfb)

inc(updateTime[rid], PER_UPD_TEMP)

if(whatTemp[rid] = 0)

whatTemp[rid] = 1

endif

; check what we have to do

select(whatTemp[rid])

case 0

return 0 ; nothing to do

case 1

sObj[rid].rid = rid

sObj[rid].objCode = 0x2101 ; Cpu drive Temp

sObj[rid].subIndex = 2

sObj[rid].type = 5 ; float data

sObj[rid].phase = 1 ; set PASS_THROUGH modality

whatTemp[rid] = 2 ; next step

; break intentionally omitted

case 2

ero = co_robj(sobj[rid])

select(ero)

default

whatTemp[rid] = 0 ; go back

return ero ; return error code

case 0

return 1 ; we have to wait

case -2 ; busy, restart again next loop

sObj[rid].phase = 1 ; set PASS_THROUGH modality for the next call

return 1

case 1 ; we got the answer and we save it

CpuDrive_temp[rid] = sObj[rid].data

break

end_select

; prepare the read next temperature

sObj[rid].objCode = 0x2101 ; Heater Temp

sObj[rid].subIndex = 1

sObj[rid].type = 5 ; float data

sObj[rid].phase = 1 ; set PASS_THROUGH modality

whatTemp[rid] = 3 ; next step

; break intentionally omitted

case 3

ero = co_robj(sobj[rid])

select(ero)

default

whatTemp[rid] = 0 ; go back

return ero ; return error code

case 0

return 1 ; we have to wait

case -2 ; busy, restart again next loop

sObj[rid].phase = 1 ; set PASS_THROUGH modality for the next call

return 1

case 1 ; we got the answer and we save it

Heater_temp[rid] = sObj[rid].data

break

end_select

sObj[rid].objCode = 0x2101 ; Control Board Temp

sObj[rid].subIndex = 0xC

sObj[rid].type = 5 ; float data

sObj[rid].phase = 1 ; set PASS_THROUGH modality

whatTemp[rid] = 4 ; next step

; break intentionally omitted

case 4

ero = co_robj(sobj[rid])

select(ero)

default

whatTemp[rid] = 0 ; go back

return ero ; return error code

case 0

return 1 ; we have to wait

case -2 ; busy, restart again next loop

sObj[rid].phase = 1 ; set PASS_THROUGH modality for the next call

return 1

case 1 ; we got the answer and we save it

ControlBoard_temp[rid] = sObj[rid].data

break

end_select

whatTemp[rid] = 0 ; end of the job ....

break

end_select

return 2 ; all temperature updated

ENDFUN

;<0><0><0><0><0><0><0><0><0><0><0><0><0><0><0><0><0><0><0><0><0>

;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

FUNCTION int ReadImdTempBL(int rid)

; routine 'BLOCKING' version

; function to update the IMD temperature value each PER_UPD_TEMP seconds.

; the information will be set in global storage.

; the function want the RID of the IMD

; give back:

; <0 error

; >2 error (SDO diagnostic)

; 0 no operation

; 2 all temperature updated

int ero, timeToRead

stru_co_obj sobj

; check RID value

if(not range(rid, 1, 32))

return -1 ; return error if illegal value

endif

timeToRead = FALSE

; check if time to update

if(updateTime[rid] <= tfb)

inc(updateTime[rid], PER_UPD_TEMP)

timeToRead = TRUE

endif

; check what we have to do

if(not timeToRead)

return 0 ; nothing to do

endif

; we can read

sObj.rid = rid

sObj.objCode = 0x2101 ; Cpu drive Temp

sObj.subIndex = 2

sObj.type = 5 ; float data

sObj.phase = -1 ; set Blocking modality

ero = co_robj(sobj)

if(ero <> 1)

return ero

endif

CpuDrive_temp[rid] = sObj.data

; prepare the read next temperature

sObj.subIndex = 1 ; Heater Temp

sObj.phase = -1 ; set PASS_THROUGH modality

ero = co_robj(sobj)

if(ero <> 1)

return ero

endif

Heater_temp[rid] = sObj.data

; prepare the read next temperature

sObj.subIndex = 0xC ; Control Board Temp

sObj.phase = -1 ; set PASS_THROUGH modality

ero = co_robj(sobj)

if(ero <> 1)

return ero

endif

ControlBoard_temp[rid] = sObj.data

return 2 ; all temperatures updated

ENDFUN

This Info:	ALT+q
Page Header:	ALT+h
Topic Header:	ALT+t
Topic Body:	ALT+b
Contents:	ALT+c
Search:	ALT+s
Exit Menu/Up:	ESC

Abilitare JavaScript per vedere questo sito.

Funzione co_robj()

Vedi: Funzioni/istruzioni, Gestione CANopen/EtherCAT (fieldbus), Comunicazione CANopen, Comunicazione EtherCAT, co_wobj()

Keyboard Navigation